wigner_distribution.F90

Go to the documentation of this file.

!! Copyright (C) 2024 M. Lueders
!!
!! This Source Code Form is subject to the terms of the Mozilla Public
!! License, v. 2.0. If a copy of the MPL was not distributed with this
!! file, You can obtain one at https://mozilla.org/MPL/2.0/.
!!
#include "global.h"
 
module wigner_distribution_oct_m
 
  use, intrinsic :: iso_fortran_env
  use debug_oct_m
  use distribution_gaussian_oct_m
  use global_oct_m
  use messages_oct_m
  use profiling_oct_m
 
  private
  public :: &
    wigner_distribution_t
 
 
  integer, parameter, public :: &
    WIGNER_Q = 1,               &
    wigner_p = 2
 
  type :: wigner_distribution_t
 
    private
 
    integer :: num_modes
    real(real64), allocatable :: random_numbers(:, :)
 
  contains
 
    procedure :: init => wigner_distribution_init  
    procedure :: end  => wigner_distribution_end   
    procedure :: get  => wigner_distribution_get   
 
  end type wigner_distribution_t
 
contains
 
  !
  subroutine wigner_distribution_init(this, num_modes, seed)
    class(wigner_distribution_t), intent(inout) :: this
    integer,                      intent(in)    :: num_modes
    integer(int64),               intent(in)    :: seed
 
    integer(int64) :: local_seed
 
    push_sub(wigner_distribution_init)
 
    assert(seed /= 0)
 
    this%num_modes = num_modes
    local_seed = seed
 
    safe_allocate(this%random_numbers(1:num_modes, 1:2))
    this%random_numbers = normal_distribution_get_random(local_seed, this%num_modes)
 
    pop_sub(wigner_distribution_init)
  end subroutine wigner_distribution_init
 
  subroutine wigner_distribution_end(this)
    class(wigner_distribution_t), intent(inout) :: this
 
    push_sub(wigner_distribution_end)
    safe_deallocate_a(this%random_numbers)
    pop_sub(wigner_distribution_end)
  end subroutine wigner_distribution_end
 
  !
  function wigner_distribution_get(this, sigma, mu, set) result(values)
    class(wigner_distribution_t), intent(inout) :: this
    real(real64),                 intent(in)    :: sigma(1:this%num_modes)
    real(real64),                 intent(in)    :: mu(1:this%num_modes)
    integer,                      intent(in)    :: set
 
    real(real64)  :: values(1:this%num_modes)
 
    push_sub(wigner_distribution_get)
 
    assert(set==wigner_q .or. set==wigner_p)
    values = sigma*this%random_numbers(:,set) + mu
 
    pop_sub(wigner_distribution_get)
  end function wigner_distribution_get
 
 
end module wigner_distribution_oct_m