wannier_opts.F90

Go to the documentation of this file.

!! Copyright (C) 2026 A. Buccheri, J. Reimann
!!
!! This program is free software; you can redistribute it and/or modify
!! it under the terms of the GNU General Public License as published by
!! the Free Software Foundation; either version 2, or (at your option)
!! any later version.
!!
!! This program is distributed in the hope that it will be useful,
!! but WITHOUT ANY WARRANTY; without even the implied warranty of
!! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
!! GNU General Public License for more details.
!!
!! You should have received a copy of the GNU General Public License
!! along with this program; if not, write to the Free Software
!! Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
!! 02110-1301, USA.
!!
 
 
#include "global.h"
 
module wannier_opts_oct_m
  use, intrinsic :: iso_fortran_env
 
  use debug_oct_m
  use global_oct_m
  use io_oct_m
  use messages_oct_m
  use namespace_oct_m
  use parser_oct_m
  use restart_oct_m
  use unit_oct_m
  use unit_system_oct_m
 
  implicit none
  private
 
  public :: &
    wannier_opts_t, &
    wannier_opts_parse_oct, &
    wannier_opts_parse_win
 
  integer, parameter, public :: &
    TD_WANNIER_METHOD_NONE = 0, &
    td_wannier_method_wannier90 = 1, &
    td_wannier_method_phase = 2
 
  type :: wannier_opts_t
    integer           :: num_bands = 0
    integer           :: num_wann = 0
    logical           :: use_scdm
    real(real64)      :: scdm_mu
    real(real64)      :: scdm_sigma
    real(real64)      :: threshold
    character(len=80) :: prefix
    integer           :: restart_from
    logical           :: plot
    logical           :: wannierize
    logical           :: calc_overlaps
    logical           :: dump_inputs
    logical           :: spinors = .false. 
    integer,      allocatable  :: spin_proj_component(:)
 
    logical, allocatable :: exclude_list(:)
    integer, allocatable :: band_index(:)
 
    ! Wigner Seitz grid options
    ! These are optional, but the values from .win file must be used if present.
    integer, dimension(3) :: ws_search_size = [2, 2, 2]
    real(real64)          :: ws_distance_tol = 1e-5 * p_ang  
 
    ! TD-related options
    integer           :: td_update_interval
    integer           :: td_method
    logical           :: td_write_hr
 
  contains
    procedure :: parse_oct => wannier_opts_parse_oct
    procedure :: parse_win => wannier_opts_parse_win
  end type wannier_opts_t
 
contains
 
  subroutine wannier_opts_parse_oct(this, namespace)
    class(wannier_opts_t), intent(inout) :: this
    type(namespace_t),  intent(in)    :: namespace
 
    logical :: read_from_td
 
    push_sub(wannier_opts_parse_oct)
 
    !%Variable Wannier90Prefix
    !%Type string
    !%Default w90
    !%Section Utilities::oct-wannier90
    !%Description
    !% Prefix for wannier90 files. Used by both oct-wannier90 and oct-wannier90lib
    !% as well as the time-dependent Wannier workflow.
    !%End
    call parse_variable(namespace, 'Wannier90Prefix', 'w90', this%prefix)
 
    !%Variable Wannier90UseTD
    !%Type logical
    !%Default no
    !%Section Utilities::oct-wannier90
    !%Description
    !% This variable controls which states are used as input into the standalone utilities
    !% oct-wannier90 and oct-wannier90lib.
    !% By default oct-wannier90 uses the ground-state states.
    !% By setting this variable to yes, oct-wannier90 will use the TD states instead.
    !% This parameter does not apply to the time-dependent Wannier workflow.
    !%End
    call parse_variable(global_namespace, 'Wannier90UseTD', .false., read_from_td)
    if (read_from_td) then
      this%restart_from = restart_td
    else
      this%restart_from = restart_gs
    end if
 
    !%Variable Wannier90DumpFiles
    !%Type logical
    !%Default no
    !%Section Utilities::oct-wannier90lib
    !%Description
    !% Whether or not to dump intermediate files to disk.
    !% This applies only to the oct-wannierlib utility.
    !% Files are: .amn, .mmn, .eig and .win with inputs.
    !%End
    call parse_variable(global_namespace, 'Wannier90DumpFiles', .false., this%dump_inputs)
 
    !%Variable Wannier90Wannierize
    !%Type logical
    !%Default yes
    !%Section Utilities::oct-wannier90lib
    !%Description
    !% Whether or not to perform the wannierization step (including disentanglement).
    !% This applies only to the standalone utility oct-wannier90lib.
    !%End
    call parse_variable(global_namespace, 'Wannier90Wannierize', .true., this%wannierize)
 
    !%Variable Wannier90Plot
    !%Type logical
    !%Default no
    !%Section Utilities::oct-wannier90lib
    !%Description
    !% If set to yes, oct-wannier90lib will generate the wannier functions on a real space
    !% grid and write them to file.
    !%End
    call parse_variable(global_namespace, 'Wannier90Plot', .false., this%plot)
 
    !%Variable Wannier90CalcOverlaps
    !%Type logical
    !%Default no
    !%Section Utilities::oct-wannier90lib
    !%Description
    !% Whether or not to calculate the amn and mmn matrices from octopus states.
    !% By setting this variable to no, oct-wannier90 will attempt to read them from files.
    !% This applies only to the standalone utility oct-wannier90lib.
    !%End
    call parse_variable(global_namespace, 'Wannier90CalcOverlaps', .false., this%calc_overlaps)
 
    !%Variable Wannier90UseSCDM
    !%Type logical
    !%Default no
    !%Section Utilities::oct-wannier90
    !%Description
    !% By default oct-wannier90 and oct-wannier90lib use the projection method to generate the .amn file.
    !% By setting this variable to yes, they will use the SCDM method instead.
    !%End
    call parse_variable(namespace, 'Wannier90UseSCDM', .false., this%use_scdm)
    if (this%use_scdm) then
      !%Variable SCDMsigma
      !%Type float
      !%Default 0.2
      !%Section Utilities::oct-wannier90
      !%Description
      !% Broadening of SCDM smearing function.
      !%End
      call parse_variable(namespace, 'SCDMsigma', 0.2_real64, this%scdm_sigma)
 
      !%Variable SCDMmu
      !%Type float
      !%Section Utilities::oct-wannier90
      !%Description
      !% Energy range up to which states are considered for SCDM.
      !%End
      call parse_variable(namespace, 'SCDMmu', m_huge, this%scdm_mu)
    end if
 
    ! We use the variable AOThreshold to deterine the threshold on the radii of the atomic orbitals
    ! TODO: Have the threshold for wannier functions different than for AO
    call parse_variable(namespace, 'AOThreshold', 0.001_real64, this%threshold)
 
    !%Variable TDWannierMethod
    !%Type integer
    !%Default 0
    !%Section Time-Dependent
    !%Description
    !% Specifies which method to use for TD Wannier calculations.
    !%Option none 0
    !% TD Wannier functionality is disabled.
    !%Option wannier90 1
    !% Performs a full wannierization of the time-dependent Kohn-Sham states to update the U matrix.
    !%Option phase 2
    !% Updates the time-dependent wannier transformation matrix U by applying the phase a static state would acquire.
    !%End
    call parse_variable(namespace, 'TDWannierMethod', 0, this%td_method)
 
    !%Variable TDWannierUpdateInterval
    !%Type integer
    !%Default 1
    !%Section Time-Dependent::TD Output
    !%Description
    !% If TDWannierMethod is enabled, Wannier-related data is updated and written
    !% every TDWannierUpdateInterval iterations.
    !%End
    call parse_variable(namespace, 'TDWannierUpdateInterval', 1, this%td_update_interval)
 
    !%Variable TDWannierWriteHR
    !%Type logical
    !%Default no
    !%Section Time-Dependent
    !%Description
    !% Whether or not TD Wannier writes w90_hr.dat file during TD run.
    !%End
    call parse_variable(namespace, 'TDWannierWriteHR', .false., this%td_write_hr)
    if (this%td_write_hr) then
      if (this%td_method == td_wannier_method_none) then
        message(1) = 'TDWannierWriteHR is set to yes, but TDWannierMethod is set to None.'
        message(2) = 'TDWannierWriteHR will be ignored.'
        call messages_warning(2)
      else
        message(1) = 'TDWannierWriteHR is set to yes. ' // &
          'Currently the time-dependent lattice models are gauge-dependent and can not be trusted.'
        call messages_warning(1)
      end if
    end if
 
    pop_sub(wannier_opts_parse_oct)
 
  end subroutine wannier_opts_parse_oct
 
  subroutine wannier_opts_parse_win(this)
    class(wannier_opts_t), intent(inout) :: this
 
    character(len=80)       :: filename, line, dummy, dummy1, dummy2
    integer                 :: w90_win, io, tmp_int
    real(real64)            :: ws_distance_tol_angstrom
    logical                 :: exist
 
    push_sub(wannier_opts_parse_win)
 
    filename = trim(adjustl(this%prefix)) //'.win'
    inquire(file=filename,exist=exist)
    if (.not. exist) then
      message(1) = 'Cannot find specified Wannier90 win file.'
      call messages_fatal(1)
    else
      message(1) = 'Reading file '//filename
      w90_win = io_open(trim(filename), action='read')
      do
        read(w90_win, '(A)', iostat=io) line
        if (is_iostat_end(io)) exit
 
        if (index(line, '=') > 0) then
          read(line, *, iostat=io) dummy, dummy2, dummy1
        else
          read(line, *, iostat=io) dummy, dummy1
        end if
        if (dummy == 'num_bands') then
          read(dummy1, *, iostat=io) tmp_int
          this%num_bands = tmp_int
        else if (dummy == 'num_wann') then
          read(dummy1, *, iostat=io) tmp_int
          this%num_wann = tmp_int
        else if (dummy == 'ws_search_size') then
          if (index(line, '=') > 0) then
            read(line, *, iostat=io) dummy, dummy2, this%ws_search_size(:)
          else
            read(line, *, iostat=io) dummy, this%ws_search_size(:)
          end if
          if (io /= 0) then
            ! Single integer: apply to all three dimensions
            read(dummy1, *, iostat=io) tmp_int
            this%ws_search_size = tmp_int
          end if
        else if (dummy == 'ws_distance_tol') then
          read(dummy1, *, iostat=io) ws_distance_tol_angstrom
          this%ws_distance_tol = units_to_atomic(unit_angstrom, ws_distance_tol_angstrom)
        end if
      end do
 
      call io_close(w90_win)
    end if
 
    pop_sub(wannier_opts_parse_win)
 
  end subroutine wannier_opts_parse_win
 
end module wannier_opts_oct_m