target_excited.F90

Go to the documentation of this file.

!! Copyright (C) 2002-2006 M. Marques, A. Castro, A. Rubio, G. Bertsch
!!
!! This program is free software; you can redistribute it and/or modify
!! it under the terms of the GNU General Public License as published by
!! the Free Software Foundation; either version 2, or (at your option)
!! any later version.
!!
!! This program is distributed in the hope that it will be useful,
!! but WITHOUT ANY WARRANTY; without even the implied warranty of
!! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
!! GNU General Public License for more details.
!!
!! You should have received a copy of the GNU General Public License
!! along with this program; if not, write to the Free Software
!! Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
!! 02110-1301, USA.
!!
 
#include "global.h"
 
module target_excited_oct_m
  use debug_oct_m
  use electron_space_oct_m
  use epot_oct_m
  use excited_states_oct_m
  use global_oct_m
  use grid_oct_m
  use hamiltonian_elec_oct_m
  use io_oct_m
  use ions_oct_m
  use ion_dynamics_oct_m
  use, intrinsic :: iso_fortran_env
  use kpoints_oct_m
  use lalg_basic_oct_m
  use lalg_adv_oct_m
  use mesh_oct_m
  use mesh_function_oct_m
  use messages_oct_m
  use namespace_oct_m
  use opt_control_global_oct_m
  use opt_control_state_oct_m
  use output_oct_m
  use output_low_oct_m
  use profiling_oct_m
  use restart_oct_m
  use space_oct_m
  use states_elec_oct_m
  use states_elec_calc_oct_m
  use states_elec_restart_oct_m
  use target_oct_m
  use td_oct_m
  use types_oct_m
 
  implicit none
 
  private
  public :: target_excited_t
 
  type, extends(target_t) :: target_excited_t
    private
    type(excited_states_t) :: est
  contains
    procedure :: init      => target_init_excited
    procedure :: j1        => target_j1_excited
    procedure :: apply_chi => target_chi_excited
    procedure :: output    => target_output_excited
  end type target_excited_t
 
 
contains
 
 
  ! ----------------------------------------------------------------------
  subroutine target_init_excited(tg, gr, kpoints, namespace, space, ions, qcs, td, w0, oct, ep, restart)
    class(target_excited_t),   intent(inout) :: tg
    type(grid_t),              intent(in)    :: gr
    type(kpoints_t),           intent(in)    :: kpoints
    type(namespace_t),         intent(in)    :: namespace
    class(space_t),            intent(in)    :: space
    type(ions_t),              intent(in)    :: ions
    type(opt_control_state_t), intent(inout) :: qcs
    type(td_t),                intent(in)    :: td
    real(real64),              intent(in)    :: w0
    type(oct_t),               intent(in)    :: oct
    type(epot_t),              intent(inout) :: ep
    type(restart_t),           intent(inout) :: restart
 
    integer :: ierr, nik, dim
 
    push_sub(target_init_excited)
 
    message(1) =  'Info: TargetOperator is a linear combination of Slater determinants.'
    call messages_info(1, namespace=namespace)
 
    tg%move_ions = td%ions_dyn%ions_move()
    tg%dt = td%dt
 
    call states_elec_look(restart, nik, dim, tg%st%nst, ierr)
    if (ierr /= 0) then
      message(1) = "Unable to read states information."
      call messages_fatal(1, namespace=namespace)
    end if
    tg%st%st_start = 1
    tg%st%st_end   = tg%st%nst
 
    safe_deallocate_a(tg%st%occ)
    safe_deallocate_a(tg%st%eigenval)
    safe_deallocate_a(tg%st%node)
 
    safe_allocate(     tg%st%occ(1:tg%st%nst, 1:tg%st%nik))
    safe_allocate(tg%st%eigenval(1:tg%st%nst, 1:tg%st%nik))
    safe_allocate(    tg%st%node(1:tg%st%nst))
    if (tg%st%d%ispin == spinors) then
      safe_deallocate_a(tg%st%spin)
      safe_allocate(tg%st%spin(1:3, 1:tg%st%nst, 1:tg%st%nik))
    end if
    call states_elec_allocate_wfns(tg%st, gr, type_cmplx)
    tg%st%node(:)  = 0
 
    call states_elec_load(restart, namespace, space, tg%st, gr, kpoints, fixed_occ=.true., ierr=ierr)
    if (ierr /= 0) then
      message(1) = "Unable to read wavefunctions."
      call messages_fatal(1, namespace=namespace)
    end if
 
    call excited_states_init(tg%est, tg%st, "oct-excited-state-target", namespace)
 
    pop_sub(target_init_excited)
  end subroutine target_init_excited
 
 
  ! ----------------------------------------------------------------------
  subroutine target_output_excited(tg, namespace, space, gr, dir, ions, hm, outp)
    class(target_excited_t), intent(inout) :: tg
    type(namespace_t),   intent(in)  :: namespace
    class(space_t),      intent(in)    :: space
    type(grid_t),        intent(in)  :: gr
    character(len=*),    intent(in)  :: dir
    type(ions_t),        intent(in)  :: ions
    type(hamiltonian_elec_t), intent(in)  :: hm
    type(output_t),      intent(in)  :: outp
 
    push_sub(target_output_excited)
 
    call io_mkdir(trim(dir), namespace)
    call output_states(outp, namespace, space, trim(dir)//'/st', tg%est%st, gr, ions, hm, -1)
    call excited_states_output(tg%est, trim(dir), namespace)
 
    pop_sub(target_output_excited)
  end subroutine target_output_excited
  ! ----------------------------------------------------------------------
 
 
  ! ----------------------------------------------------------------------
  real(real64) function target_j1_excited(tg, namespace, gr, kpoints, qcpsi, ions) result(j1)
    class(target_excited_t),     intent(inout) :: tg
    type(namespace_t),           intent(in)    :: namespace
    type(grid_t),                intent(in)    :: gr
    type(kpoints_t),             intent(in)    :: kpoints
    type(opt_control_state_t),   intent(inout) :: qcpsi
    type(ions_t),      optional, intent(in)    :: ions
 
    type(states_elec_t), pointer :: psi
 
    push_sub(target_j1_excited)
 
    psi => opt_control_point_qs(qcpsi)
 
    j1 = abs(zstates_elec_mpdotp(namespace, gr, tg%est, psi))**2
 
    nullify(psi)
    pop_sub(target_j1_excited)
  end function target_j1_excited
 
 
  ! ----------------------------------------------------------------------
  subroutine target_chi_excited(tg, namespace, gr, kpoints, qcpsi_in, qcchi_out, ions)
    class(target_excited_t),           intent(inout) :: tg
    type(namespace_t),                 intent(in)    :: namespace
    type(grid_t),                      intent(in)    :: gr
    type(kpoints_t),                   intent(in)    :: kpoints
    type(opt_control_state_t), target, intent(inout) :: qcpsi_in
    type(opt_control_state_t), target, intent(inout) :: qcchi_out
    type(ions_t),                      intent(in)    :: ions
 
    complex(real64), allocatable :: cI(:), dI(:), mat(:, :, :), mm(:, :, :, :), mk(:, :), lambda(:, :)
    complex(real64), allocatable :: zpsi(:, :), zchi(:, :)
    integer :: ik, ist, jst, ia, ib, n_pairs, nst, nik, jj, idim, ip
    type(states_elec_t), pointer :: psi_in, chi_out
    push_sub(target_chi_excited)
 
    psi_in => opt_control_point_qs(qcpsi_in)
    chi_out => opt_control_point_qs(qcchi_out)
 
    n_pairs = tg%est%n_pairs
    nik = psi_in%nik
    nst = psi_in%nst
 
 
    safe_allocate(zpsi(1:gr%np, 1:psi_in%d%dim))
    safe_allocate(zchi(1:gr%np, 1:psi_in%d%dim))
    safe_allocate(ci(1:n_pairs))
    safe_allocate(di(1:n_pairs))
    safe_allocate(mat(1:tg%est%st%nst, 1:nst, 1:psi_in%nik))
    safe_allocate(mm(1:nst, 1:nst, 1:nik, 1:n_pairs))
    safe_allocate(mk(1:gr%np_part, 1:psi_in%d%dim))
    safe_allocate(lambda(1:n_pairs, 1:n_pairs))
 
    call zstates_elec_matrix(tg%est%st, psi_in, gr, mat)
 
    do ia = 1, n_pairs
      ci(ia) = tg%est%weight(ia)
      call zstates_elec_matrix_swap(mat, tg%est%pair(ia))
      mm(1:nst, 1:nst, 1:nik, ia) = mat(1:nst, 1:nik, 1:nik)
      di(ia) = zstates_elec_mpdotp(namespace, gr, tg%est%st, psi_in, mat)
      if (abs(di(ia)) > 1.0e-12_real64) then
        do ik = 1, nik
          call lalg_inverse(nst, mm(1:nst, 1:nst, ik, ia), 'dir')
        end do
      end if
      call zstates_elec_matrix_swap(mat, tg%est%pair(ia))
    end do
 
    do ia = 1, n_pairs
      do ib = 1, n_pairs
        lambda(ia, ib) = conjg(ci(ib)) * ci(ia) * conjg(di(ia)) * di(ib)
      end do
    end do
 
    select case (psi_in%d%ispin)
    case (unpolarized)
      write(message(1), '(a)') 'Internal error in target.target_chi: unpolarized.'
      call messages_fatal(1, namespace=namespace)
 
    case (spin_polarized)
      assert(chi_out%nik == 2)
 
      do ik = 1, nik
        do ist = chi_out%st_start, chi_out%st_end
 
          zchi(1:gr%np, 1:psi_in%d%dim) = m_z0
 
          do ia = 1, n_pairs
            if (ik /= tg%est%pair(ia)%kk) cycle
            if (abs(di(ia)) < 1.0e-12_real64) cycle
            do ib = 1, n_pairs
              if (abs(di(ib)) < 1.0e-12_real64) cycle
              mk = m_z0
 
              do jst = 1, nst
                if (jst == tg%est%pair(ib)%i) jj = tg%est%pair(ia)%a
                call states_elec_get_state(tg%est%st, gr, jj, ik, zpsi)
 
                do idim = 1, psi_in%d%dim
                  do ip = 1, gr%np
                    mk(ip, idim) = mk(ip, idim) + conjg(mm(ist, jst, ik, ib))*zpsi(ip, idim)
                  end do
                end do
              end do
 
              call lalg_axpy(gr%np_part, psi_in%d%dim, m_z1*lambda(ib, ia), mk, zchi)
 
            end do
          end do
 
          call states_elec_set_state(chi_out, gr, ist, ik, zchi)
 
        end do
      end do
 
    case (spinors)
      assert(chi_out%nik == 1)
 
      do ist = chi_out%st_start, chi_out%st_end
 
        zchi(1:gr%np, 1:psi_in%d%dim) = m_z0
 
        do ia = 1, n_pairs
          if (abs(di(ia)) < 1.0e-12_real64) cycle
 
          do ib = 1, n_pairs
            if (abs(di(ib)) < 1.0e-12_real64) cycle
 
            mk = m_z0
            do jst = 1, nst
              if (jst == tg%est%pair(ib)%i) jj = tg%est%pair(ia)%a
              call states_elec_get_state(tg%est%st, gr, jj, ik, zpsi)
 
              do idim = 1, psi_in%d%dim
                do ip = 1, gr%np
                  mk(ip, idim) = mk(ip, idim) + conjg(mm(ist, jst, 1, ib))*zpsi(ip, idim)
                end do
              end do
            end do
 
            call lalg_axpy(gr%np_part, 2, m_z1*lambda(ib, ia), mk, zchi)
          end do
        end do
 
        call states_elec_set_state(chi_out, gr, ist, ik, zchi)
 
      end do
 
    end select
 
    safe_deallocate_a(zpsi)
    safe_deallocate_a(zchi)
    safe_deallocate_a(ci)
    safe_deallocate_a(di)
    safe_deallocate_a(mat)
    safe_deallocate_a(mm)
    safe_deallocate_a(mk)
    safe_deallocate_a(lambda)
    nullify(psi_in)
    nullify(chi_out)
    pop_sub(target_chi_excited)
  end subroutine target_chi_excited
 
end module target_excited_oct_m
 
!! Local Variables:
!! mode: f90
!! coding: utf-8
!! End: