target_exclude.F90

Go to the documentation of this file.

!! Copyright (C) 2002-2006 M. Marques, A. Castro, A. Rubio, G. Bertsch
!!
!! This program is free software; you can redistribute it and/or modify
!! it under the terms of the GNU General Public License as published by
!! the Free Software Foundation; either version 2, or (at your option)
!! any later version.
!!
!! This program is distributed in the hope that it will be useful,
!! but WITHOUT ANY WARRANTY; without even the implied warranty of
!! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
!! GNU General Public License for more details.
!!
!! You should have received a copy of the GNU General Public License
!! along with this program; if not, write to the Free Software
!! Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
!! 02110-1301, USA.
!!
 
 
#include "global.h"
 
module target_exclude_oct_m
  use debug_oct_m
  use epot_oct_m
  use global_oct_m
  use grid_oct_m
  use hamiltonian_elec_oct_m
  use io_oct_m
  use ions_oct_m
  use ion_dynamics_oct_m
  use, intrinsic :: iso_fortran_env
  use kpoints_oct_m
  use loct_oct_m
  use mesh_oct_m
  use mesh_function_oct_m
  use messages_oct_m
  use namespace_oct_m
  use opt_control_global_oct_m
  use opt_control_state_oct_m
  use output_oct_m
  use output_low_oct_m
  use parser_oct_m
  use profiling_oct_m
  use restart_oct_m
  use space_oct_m
  use states_elec_oct_m
  use states_elec_restart_oct_m
  use target_oct_m
  use td_oct_m
 
  implicit none
 
  private
  public :: target_exclude_t
 
  type, extends(target_t) :: target_exclude_t
    private
    character(len=80) :: excluded_states_list
  contains
    procedure :: init      => target_init_exclude
    procedure :: j1        => target_j1_exclude
    procedure :: apply_chi => target_chi_exclude
    procedure :: output    => target_output_exclude
  end type target_exclude_t
 
 
contains
 
  ! ----------------------------------------------------------------------
  subroutine target_init_exclude(tg, gr, kpoints, namespace, space, ions, qcs, td, w0, oct, ep, restart)
    class(target_exclude_t),   intent(inout) :: tg
    type(grid_t),              intent(in)    :: gr
    type(kpoints_t),           intent(in)    :: kpoints
    type(namespace_t),         intent(in)    :: namespace
    class(space_t),            intent(in)    :: space
    type(ions_t),              intent(in)    :: ions
    type(opt_control_state_t), intent(inout) :: qcs
    type(td_t),                intent(in)    :: td
    real(real64),              intent(in)    :: w0
    type(oct_t),               intent(in)    :: oct
    type(epot_t),              intent(inout) :: ep
    type(restart_t),           intent(inout) :: restart
 
    push_sub(target_init_exclude)
 
    tg%move_ions = td%ions_dyn%ions_move()
    tg%dt = td%dt
 
    message(1) =  'Info: The target functional is the exclusion of a number of states defined by'
    message(2) =  '      "OCTExcludedStates".'
    call messages_info(2, namespace=namespace)
    !%Variable OCTExcludedStates
    !%Type string
    !%Section Calculation Modes::Optimal Control
    !%Description
    !% If the target is the exclusion of several targets, ("OCTTargetOperator = oct_exclude_states")
    !% then you must declare which states are to be excluded, by setting the OCTExcludedStates variable.
    !% It must be a string in "list" format: "1-8", or "2,3,4-9", for example. Be careful to include
    !% in this list only states that have been calculated in a previous "gs" or "unocc" calculation,
    !% or otherwise the error will be silently ignored.
    !%End
    call parse_variable(namespace, 'OCTExcludedStates', '1', tg%excluded_states_list)
    call states_elec_deallocate_wfns(tg%st)
 
    call states_elec_look_and_load(restart, namespace, space, tg%st, gr, kpoints, fixed_occ=.true.)
 
    pop_sub(target_init_exclude)
  end subroutine target_init_exclude
 
 
  ! ----------------------------------------------------------------------
  subroutine target_output_exclude(tg, namespace, space, gr, dir, ions, hm, outp)
    class(target_exclude_t), intent(inout) :: tg
    type(namespace_t),   intent(in) :: namespace
    class(space_t),      intent(in) :: space
    type(grid_t),        intent(in) :: gr
    character(len=*),    intent(in) :: dir
    type(ions_t),        intent(in) :: ions
    type(hamiltonian_elec_t), intent(in) :: hm
    type(output_t),      intent(in) :: outp
 
    push_sub(target_output_exclude)
 
    call io_mkdir(trim(dir), namespace)
    call output_states(outp, namespace, space, trim(dir), tg%st, gr, ions, hm, -1)
 
    pop_sub(target_output_exclude)
  end subroutine target_output_exclude
  ! ----------------------------------------------------------------------
 
 
  ! ----------------------------------------------------------------------
  real(real64) function target_j1_exclude(tg, namespace, gr, kpoints, qcpsi, ions) result(j1)
    class(target_exclude_t),     intent(inout) :: tg
    type(namespace_t),           intent(in)    :: namespace
    type(grid_t),                intent(in)    :: gr
    type(kpoints_t),             intent(in)    :: kpoints
    type(opt_control_state_t),   intent(inout) :: qcpsi
    type(ions_t),      optional, intent(in)    :: ions
 
    integer :: ist
    complex(real64), allocatable :: zpsi1(:, :), zpsi(:, :)
    type(states_elec_t), pointer :: psi
 
    push_sub(target_j1_exclude)
 
    psi => opt_control_point_qs(qcpsi)
 
    safe_allocate(zpsi(1:gr%np, 1:tg%st%d%dim))
    safe_allocate(zpsi1(1:gr%np, 1:tg%st%d%dim))
 
    call states_elec_get_state(psi, gr, 1, 1, zpsi1)
 
    j1 = m_one
    do ist = 1, tg%st%nst
      if (loct_isinstringlist(ist, tg%excluded_states_list)) then
        call states_elec_get_state(tg%st, gr, ist, 1, zpsi)
        j1 = j1 - abs(zmf_dotp(gr, psi%d%dim, zpsi, zpsi1))**2
      end if
    end do
 
    safe_deallocate_a(zpsi)
    safe_deallocate_a(zpsi1)
 
    nullify(psi)
    pop_sub(target_j1_exclude)
  end function target_j1_exclude
 
 
  ! ----------------------------------------------------------------------
  subroutine target_chi_exclude(tg, namespace, gr, kpoints, qcpsi_in, qcchi_out, ions)
    class(target_exclude_t),           intent(inout) :: tg
    type(namespace_t),                 intent(in)    :: namespace
    type(grid_t),                      intent(in)    :: gr
    type(kpoints_t),                   intent(in)    :: kpoints
    type(opt_control_state_t), target, intent(inout) :: qcpsi_in
    type(opt_control_state_t), target, intent(inout) :: qcchi_out
    type(ions_t),                      intent(in)    :: ions
 
    integer :: ist, ib
    complex(real64) :: olap
    complex(real64), allocatable :: zpsi(:, :), zst(:, :), zchi(:, :)
    type(states_elec_t), pointer :: psi_in, chi_out
    push_sub(target_chi_exclude)
 
    psi_in => opt_control_point_qs(qcpsi_in)
    chi_out => opt_control_point_qs(qcchi_out)
 
    do ib = chi_out%group%block_start, chi_out%group%block_end
      call psi_in%group%psib(ib, 1)%copy_data_to(gr%np, chi_out%group%psib(ib, 1))
    end do
 
    safe_allocate(zpsi(1:gr%np, 1:tg%st%d%dim))
    safe_allocate(zst(1:gr%np, 1:tg%st%d%dim))
    safe_allocate(zchi(1:gr%np, 1:tg%st%d%dim))
 
    call states_elec_get_state(chi_out, gr, 1, 1, zchi)
 
    do ist = 1, tg%st%nst
      if (loct_isinstringlist(ist, tg%excluded_states_list)) then
        call states_elec_get_state(psi_in, gr, ist, 1, zpsi)
        call states_elec_get_state(tg%st, gr, ist, 1, zst)
        olap = zmf_dotp(gr, psi_in%d%dim, zst, zpsi)
        zchi(1:gr%np, 1:tg%st%d%dim) = zchi(1:gr%np, 1:tg%st%d%dim) - olap*zst(1:gr%np, 1:tg%st%d%dim)
      end if
    end do
 
    call states_elec_set_state(chi_out, gr, 1, 1, zchi)
 
    safe_deallocate_a(zpsi)
    safe_deallocate_a(zst)
    safe_deallocate_a(zchi)
 
    nullify(psi_in)
    nullify(chi_out)
    pop_sub(target_chi_exclude)
  end subroutine target_chi_exclude
 
end module target_exclude_oct_m
 
!! Local Variables:
!! mode: f90
!! coding: utf-8
!! End: