target_gstransformation.F90

Go to the documentation of this file.

!! Copyright (C) 2002-2006 M. Marques, A. Castro, A. Rubio, G. Bertsch
!!
!! This program is free software; you can redistribute it and/or modify
!! it under the terms of the GNU General Public License as published by
!! the Free Software Foundation; either version 2, or (at your option)
!! any later version.
!!
!! This program is distributed in the hope that it will be useful,
!! but WITHOUT ANY WARRANTY; without even the implied warranty of
!! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
!! GNU General Public License for more details.
!!
!! You should have received a copy of the GNU General Public License
!! along with this program; if not, write to the Free Software
!! Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
!! 02110-1301, USA.
!!
 
#include "global.h"
 
module target_gstransformation_oct_m
  use debug_oct_m
  use density_oct_m
  use epot_oct_m
  use global_oct_m
  use grid_oct_m
  use hamiltonian_elec_oct_m
  use io_oct_m
  use ions_oct_m
  use ion_dynamics_oct_m
  use, intrinsic :: iso_fortran_env
  use kpoints_oct_m
  use mesh_function_oct_m
  use messages_oct_m
  use namespace_oct_m
  use opt_control_global_oct_m
  use opt_control_state_oct_m
  use output_oct_m
  use output_low_oct_m
  use parser_oct_m
  use profiling_oct_m
  use restart_oct_m
  use space_oct_m
  use states_elec_oct_m
  use states_elec_restart_oct_m
  use target_oct_m
  use td_oct_m
 
  implicit none
 
  private
  public :: target_gstransformation_t
 
  type, extends(target_t) :: target_gstransformation_t
  contains
    procedure :: init      => target_init_gstransformation
    procedure :: j1        => target_j1_gstransformation
    procedure :: apply_chi => target_chi_gstransformation
    procedure :: output    => target_output_gstransformation
  end type target_gstransformation_t
 
 
contains
 
  ! ----------------------------------------------------------------------
  subroutine target_init_gstransformation(tg, gr, kpoints, namespace, space, ions, qcs, td, w0, oct, ep, restart)
    class(target_gstransformation_t), intent(inout) :: tg
    type(grid_t),                     intent(in)    :: gr
    type(kpoints_t),                  intent(in)    :: kpoints
    type(namespace_t),                intent(in)    :: namespace
    class(space_t),                   intent(in)    :: space
    type(ions_t),                     intent(in)    :: ions
    type(opt_control_state_t),        intent(inout) :: qcs
    type(td_t),                       intent(in)    :: td
    real(real64),                     intent(in)    :: w0
    type(oct_t),                      intent(in)    :: oct
    type(epot_t),                     intent(inout) :: ep
    type(restart_t),                  intent(inout) :: restart
 
    push_sub(target_init_gstransformation)
 
    message(1) =  'Info: Using Superposition of States for TargetOperator'
    call messages_info(1, namespace=namespace)
 
    tg%move_ions = td%ions_dyn%ions_move()
    tg%dt = td%dt
 
    !%Variable OCTTargetTransformStates
    !%Type block
    !%Default no
    !%Section Calculation Modes::Optimal Control
    !%Description
    !% If <tt>OCTTargetOperator = oct_tg_gstransformation</tt>, you must specify a
    !% <tt>OCTTargetTransformStates</tt> block, in order to specify which linear
    !% combination of the states present in <tt>restart/gs</tt> is used to
    !% create the target state.
    !%
    !% The syntax is the same as the <tt>TransformStates</tt> block.
    !%End
    call states_elec_transform(tg%st, namespace, space, restart, gr, kpoints, prefix = "OCTTarget")
 
    if (.not. parse_is_defined(namespace, 'OCTTargetTransformStates')) then
      message(1) = 'If "OCTTargetOperator = oct_tg_superposition", then you must'
      message(2) = 'supply an "OCTTargetTransformStates" block to create the superposition.'
      call messages_fatal(2, namespace=namespace)
    end if
    call density_calc(tg%st, gr, tg%st%rho)
 
    pop_sub(target_init_gstransformation)
  end subroutine target_init_gstransformation
 
 
  ! ----------------------------------------------------------------------
  subroutine target_output_gstransformation(tg, namespace, space, gr, dir, ions, hm, outp)
    class(target_gstransformation_t), intent(inout) :: tg
    type(namespace_t),   intent(in) :: namespace
    class(space_t),      intent(in) :: space
    type(grid_t),        intent(in) :: gr
    character(len=*),    intent(in) :: dir
    type(ions_t),        intent(in) :: ions
    type(hamiltonian_elec_t), intent(in) :: hm
    type(output_t),      intent(in) :: outp
    push_sub(target_output_gstransformation)
 
    call io_mkdir(trim(dir), namespace)
    call output_states(outp, namespace, space, trim(dir), tg%st, gr, ions, hm, -1)
 
    pop_sub(target_output_gstransformation)
  end subroutine target_output_gstransformation
  ! ----------------------------------------------------------------------
 
 
 
  ! ----------------------------------------------------------------------
  real(real64) function target_j1_gstransformation(tg, namespace, gr, kpoints, qcpsi, ions) result(j1)
    class(target_gstransformation_t), intent(inout) :: tg
    type(namespace_t),           intent(in)    :: namespace
    type(grid_t),                intent(in)    :: gr
    type(kpoints_t),             intent(in)    :: kpoints
    type(opt_control_state_t),   intent(inout) :: qcpsi
    type(ions_t),      optional, intent(in)    :: ions
 
    integer :: ik, ist
 
    complex(real64), allocatable :: zpsi(:, :), zst(:, :)
    type(states_elec_t), pointer :: psi
 
    push_sub(target_j1_gstransformation)
 
    psi => opt_control_point_qs(qcpsi)
 
    safe_allocate(zpsi(1:gr%np, 1:tg%st%d%dim))
    safe_allocate(zst(1:gr%np, 1:tg%st%d%dim))
 
    j1 = m_zero
    do ik = 1, psi%nik
      do ist = psi%st_start, psi%st_end
 
        call states_elec_get_state(psi, gr, ist, ik, zpsi)
        call states_elec_get_state(tg%st, gr, ist, ik, zst)
 
        j1 = j1 + abs(zmf_dotp(gr, psi%d%dim, zpsi, zst))**2
 
      end do
    end do
 
    safe_deallocate_a(zpsi)
    safe_deallocate_a(zst)
 
    nullify(psi)
    pop_sub(target_j1_gstransformation)
  end function target_j1_gstransformation
 
 
  ! ----------------------------------------------------------------------
  subroutine target_chi_gstransformation(tg, namespace, gr, kpoints, qcpsi_in, qcchi_out, ions)
    class(target_gstransformation_t),  intent(inout) :: tg
    type(namespace_t),                 intent(in)    :: namespace
    type(grid_t),                      intent(in)    :: gr
    type(kpoints_t),                   intent(in)    :: kpoints
    type(opt_control_state_t), target, intent(inout) :: qcpsi_in
    type(opt_control_state_t), target, intent(inout) :: qcchi_out
    type(ions_t),                      intent(in)    :: ions
 
    integer :: ik, ist
    complex(real64) :: olap
    complex(real64), allocatable :: zpsi(:, :), zst(:, :), zchi(:, :)
    type(states_elec_t), pointer :: psi_in, chi_out
 
    push_sub(target_chi_gstransformation)
 
    psi_in => opt_control_point_qs(qcpsi_in)
    chi_out => opt_control_point_qs(qcchi_out)
 
    safe_allocate(zpsi(1:gr%np, 1:tg%st%d%dim))
    safe_allocate(zst(1:gr%np, 1:tg%st%d%dim))
    safe_allocate(zchi(1:gr%np, 1:tg%st%d%dim))
 
    do ik = 1, psi_in%nik
      do ist = psi_in%st_start, psi_in%st_end
 
        call states_elec_get_state(psi_in, gr, ist, ik, zpsi)
        call states_elec_get_state(tg%st, gr, ist, ik, zst)
 
        olap = zmf_dotp(gr, zst(:, 1), zpsi(:, 1))
        zchi(1:gr%np, 1:tg%st%d%dim) = olap*zst(1:gr%np, 1:tg%st%d%dim)
 
        call states_elec_set_state(chi_out, gr, ist, ik, zchi)
 
      end do
    end do
 
    safe_deallocate_a(zpsi)
    safe_deallocate_a(zst)
    safe_deallocate_a(zchi)
 
    nullify(psi_in)
    nullify(chi_out)
    pop_sub(target_chi_gstransformation)
  end subroutine target_chi_gstransformation
 
end module target_gstransformation_oct_m
 
!! Local Variables:
!! mode: f90
!! coding: utf-8
!! End: