target_local.F90

Go to the documentation of this file.

!! Copyright (C) 2002-2006 M. Marques, A. Castro, A. Rubio, G. Bertsch
!!
!! This program is free software; you can redistribute it and/or modify
!! it under the terms of the GNU General Public License as published by
!! the Free Software Foundation; either version 2, or (at your option)
!! any later version.
!!
!! This program is distributed in the hope that it will be useful,
!! but WITHOUT ANY WARRANTY; without even the implied warranty of
!! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
!! GNU General Public License for more details.
!!
!! You should have received a copy of the GNU General Public License
!! along with this program; if not, write to the Free Software
!! Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
!! 02110-1301, USA.
!!
 
 
#include "global.h"
 
module target_local_oct_m
  use debug_oct_m
  use epot_oct_m
  use global_oct_m
  use grid_oct_m
  use hamiltonian_elec_oct_m
  use ions_oct_m
  use ion_dynamics_oct_m
  use io_oct_m
  use io_function_oct_m
  use, intrinsic :: iso_fortran_env
  use kpoints_oct_m
  use mesh_oct_m
  use mesh_function_oct_m
  use messages_oct_m
  use namespace_oct_m
  use opt_control_global_oct_m
  use opt_control_state_oct_m
  use output_low_oct_m
  use parser_oct_m
  use profiling_oct_m
  use restart_oct_m
  use space_oct_m
  use states_elec_oct_m
  use string_oct_m
  use target_oct_m
  use td_oct_m
  use unit_oct_m
  use unit_system_oct_m
 
 
  implicit none
 
  private
  public :: target_local_t
 
  type, extends(target_t) :: target_local_t
    private
    real(real64), allocatable :: rho(:)
  contains
    procedure :: init      => target_init_local
    procedure :: cleanup   => target_end_local
    procedure :: j1        => target_j1_local
    procedure :: apply_chi => target_chi_local
    procedure :: output    => target_output_local
  end type target_local_t
 
 
contains
 
 
  ! ----------------------------------------------------------------------
  subroutine target_init_local(tg, gr, kpoints, namespace, space, ions, qcs, td, w0, oct, ep, restart)
    class(target_local_t),     intent(inout) :: tg
    type(grid_t),              intent(in)    :: gr
    type(kpoints_t),           intent(in)    :: kpoints
    type(namespace_t),         intent(in)    :: namespace
    class(space_t),            intent(in)    :: space
    type(ions_t),              intent(in)    :: ions
    type(opt_control_state_t), intent(inout) :: qcs
    type(td_t),                intent(in)    :: td
    real(real64),              intent(in)    :: w0
    type(oct_t),               intent(in)    :: oct
    type(epot_t),              intent(inout) :: ep
    type(restart_t),           intent(inout) :: restart
 
    integer             :: ip
    real(real64)        :: xx(1:gr%box%dim), rr, psi_re, psi_im
    character(len=1024) :: expression
    push_sub(target_init_local)
 
    tg%move_ions = td%ions_dyn%ions_move()
    tg%dt = td%dt
 
    !%Variable OCTLocalTarget
    !%Type string
    !%Section Calculation Modes::Optimal Control
    !%Description
    !% If <tt>OCTTargetOperator = oct_tg_local</tt>, then one must supply a function
    !% that defines the target. This should be done by defining it through a string, using
    !% the variable <tt>OCTLocalTarget</tt>.
    !%End
    if (parse_is_defined(namespace, 'OCTLocalTarget')) then
      safe_allocate(tg%rho(1:gr%np))
      tg%rho = m_zero
      call parse_variable(namespace, 'OCTLocalTarget', "0", expression)
      call conv_to_c_string(expression)
      do ip = 1, gr%np
        call mesh_r(gr, ip, rr, coords = xx)
        ! parse user-defined expression
        call parse_expression(psi_re, psi_im, gr%box%dim, xx, rr, m_zero, expression)
        tg%rho(ip) = psi_re
      end do
    else
      message(1) = 'If OCTTargetOperator = oct_tg_local, then you must give the shape'
      message(2) = 'of this target in variable "OCTLocalTarget".'
      call messages_fatal(2, namespace=namespace)
    end if
 
    pop_sub(target_init_local)
  end subroutine target_init_local
 
 
  ! ----------------------------------------------------------------------
  subroutine target_end_local(tg, oct)
    class(target_local_t), intent(inout) :: tg
    type(oct_t),           intent(in)    :: oct
 
    push_sub(target_end_local)
 
    safe_deallocate_a(tg%rho)
 
    pop_sub(target_end_local)
  end subroutine target_end_local
 
 
  ! ----------------------------------------------------------------------
  subroutine target_output_local(tg, namespace, space, gr, dir, ions, hm, outp)
    class(target_local_t), intent(inout) :: tg
    type(namespace_t), intent(in) :: namespace
    class(space_t),    intent(in) :: space
    type(grid_t),      intent(in) :: gr
    character(len=*),  intent(in) :: dir
    type(ions_t),      intent(in) :: ions
    type(hamiltonian_elec_t), intent(in) :: hm
    type(output_t),    intent(in) :: outp
 
    integer :: ierr
    push_sub(target_output_local)
 
    call io_mkdir(trim(dir), namespace)
    call dio_function_output(outp%how(0), trim(dir), 'local_target', namespace, space, gr, &
      tg%rho, units_out%length**(-space%dim), ierr, pos=ions%pos, atoms=ions%atom)
 
 
    pop_sub(target_output_local)
  end subroutine target_output_local
  ! ----------------------------------------------------------------------
 
 
  ! ----------------------------------------------------------------------
  real(real64) function target_j1_local(tg, namespace, gr, kpoints, qcpsi, ions) result(j1)
    class(target_local_t),       intent(inout) :: tg
    type(namespace_t),           intent(in)    :: namespace
    type(grid_t),                intent(in)    :: gr
    type(kpoints_t),             intent(in)    :: kpoints
    type(opt_control_state_t),   intent(inout) :: qcpsi
    type(ions_t),      optional, intent(in)    :: ions
 
    integer :: is
    type(states_elec_t), pointer :: psi
    push_sub(target_j1_local)
 
    psi => opt_control_point_qs(qcpsi)
 
    j1 = m_zero
    do is = 1, psi%d%spin_channels
      j1 = j1 + dmf_dotp(gr, tg%rho, psi%rho(:, is))
    end do
 
    nullify(psi)
    pop_sub(target_j1_local)
  end function target_j1_local
 
 
  ! ----------------------------------------------------------------------
  subroutine target_chi_local(tg, namespace, gr, kpoints, qcpsi_in, qcchi_out, ions)
    class(target_local_t),             intent(inout) :: tg
    type(namespace_t),                 intent(in)    :: namespace
    type(grid_t),                      intent(in)    :: gr
    type(kpoints_t),                   intent(in)    :: kpoints
    type(opt_control_state_t), target, intent(inout) :: qcpsi_in
    type(opt_control_state_t), target, intent(inout) :: qcchi_out
    type(ions_t),                      intent(in)    :: ions
 
    integer :: ik, idim, ist, ip
    complex(real64), allocatable :: zpsi(:, :)
    type(states_elec_t), pointer :: psi_in, chi_out
 
    push_sub(target_chi_local)
 
    psi_in => opt_control_point_qs(qcpsi_in)
    chi_out => opt_control_point_qs(qcchi_out)
 
    safe_allocate(zpsi(1:gr%np, 1:psi_in%d%dim))
 
    do ik = 1, psi_in%nik
      do idim = 1, psi_in%d%dim
        do ist = psi_in%st_start, psi_in%st_end
          call states_elec_get_state(psi_in, gr, ist, ik, zpsi)
          do ip = 1, gr%np
            zpsi(ip, idim) = psi_in%occ(ist, ik)*tg%rho(ip)*zpsi(ip, idim)
          end do
          call states_elec_set_state(chi_out, gr, ist, ik, zpsi)
        end do
      end do
    end do
 
    safe_deallocate_a(zpsi)
 
    nullify(psi_in)
    nullify(chi_out)
    pop_sub(target_chi_local)
  end subroutine target_chi_local
 
end module target_local_oct_m
 
!! Local Variables:
!! mode: f90
!! coding: utf-8
!! End: