target_spin.F90

Go to the documentation of this file.

!! Copyright (C) 2002-2006 M. Marques, A. Castro, A. Rubio, G. Bertsch
!!
!! This program is free software; you can redistribute it and/or modify
!! it under the terms of the GNU General Public License as published by
!! the Free Software Foundation; either version 2, or (at your option)
!! any later version.
!!
!! This program is distributed in the hope that it will be useful,
!! but WITHOUT ANY WARRANTY; without even the implied warranty of
!! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
!! GNU General Public License for more details.
!!
!! You should have received a copy of the GNU General Public License
!! along with this program; if not, write to the Free Software
!! Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
!! 02110-1301, USA.
!!
 
#include "global.h"
 
module target_spin_oct_m
  use debug_oct_m
  use epot_oct_m
  use global_oct_m
  use grid_oct_m
  use hamiltonian_elec_oct_m
  use ions_oct_m
  use, intrinsic :: iso_fortran_env
  use kpoints_oct_m
  use mesh_function_oct_m
  use messages_oct_m
  use namespace_oct_m
  use opt_control_global_oct_m
  use opt_control_state_oct_m
  use output_low_oct_m
  use parser_oct_m
  use profiling_oct_m
  use restart_oct_m
  use space_oct_m
  use states_elec_oct_m
  use target_oct_m
  use td_oct_m
 
  implicit none
 
  private
  public :: target_spin_t
 
  type, extends(target_t) :: target_spin_t
    private
    complex(real64) :: spin_matrix(2, 2)
  contains
    procedure :: init      => target_init_spin
    procedure :: j1        => target_j1_spin
    procedure :: apply_chi => target_chi_spin
    procedure :: output    => target_output_spin
  end type target_spin_t
 
 
contains
 
  ! ----------------------------------------------------------------------
  subroutine target_init_spin(tg, gr, kpoints, namespace, space, ions, qcs, td, w0, oct, ep, restart)
    class(target_spin_t),      intent(inout) :: tg
    type(grid_t),              intent(in)    :: gr
    type(kpoints_t),           intent(in)    :: kpoints
    type(namespace_t),         intent(in)    :: namespace
    class(space_t),            intent(in)    :: space
    type(ions_t),              intent(in)    :: ions
    type(opt_control_state_t), intent(inout) :: qcs
    type(td_t),                intent(in)    :: td
    real(real64),              intent(in)    :: w0
    type(oct_t),               intent(in)    :: oct
    type(epot_t),              intent(inout) :: ep
    type(restart_t),           intent(inout) :: restart
 
    type(block_t)       :: blk
    integer :: jst
    complex(real64) :: alpha(3)
 
    push_sub(target_init_spin)
 
 
    message(1) =  'Info: Using a spin target'
    call messages_info(1, namespace=namespace)
 
    !%Variable OCTTargetSpin
    !%Type block
    !%Section Calculation Modes::Optimal Control
    !%Description
    !% (Experimental) Specify the targeted spin as a 3-component vector. It will be normalized.
    !%End
    if (parse_is_defined(namespace, 'OCTTargetSpin')) then
      if (parse_block(namespace, 'OCTTargetSpin', blk) == 0) then
        alpha = m_z0
        do jst = 1, parse_block_cols(blk, 0)
          call parse_block_cmplx(blk, 0, jst - 1, alpha(jst))
        end do
        call parse_block_end(blk)
 
        alpha = alpha/norm2(abs(alpha))
 
        tg%spin_matrix(1, 1) = alpha(3)
        tg%spin_matrix(2, 2) = -alpha(3)
        tg%spin_matrix(1, 2) = alpha(1) - m_zi * alpha(2)
        tg%spin_matrix(2, 1) = alpha(1) + m_zi * alpha(2)
 
      else
        call messages_variable_is_block(namespace, 'OCTTargetSpin')
      end if
 
    else
      message(1) = 'If "OCTTargetOperator = oct_tg_spin", then you must'
      message(2) = 'supply a "OCTTargetSpin" block.'
      call messages_fatal(2, namespace=namespace)
    end if
 
 
    pop_sub(target_init_spin)
  end subroutine target_init_spin
 
 
  ! ----------------------------------------------------------------------
  subroutine target_output_spin(tg, namespace, space, gr, dir, ions, hm, outp)
    class(target_spin_t),     intent(inout) :: tg
    type(namespace_t),        intent(in)    :: namespace
    class(space_t),           intent(in)    :: space
    type(grid_t),             intent(in)    :: gr
    character(len=*),         intent(in)    :: dir
    type(ions_t),             intent(in)    :: ions
    type(hamiltonian_elec_t), intent(in)    :: hm
    type(output_t),           intent(in)    :: outp
 
    push_sub(target_output_spin)
    pop_sub(target_output_spin)
  end subroutine target_output_spin
  ! ----------------------------------------------------------------------
 
 
  ! ----------------------------------------------------------------------
  real(real64) function target_j1_spin(tg, namespace, gr, kpoints, qcpsi, ions) result(j1)
    class(target_spin_t),        intent(inout) :: tg
    type(namespace_t),           intent(in)    :: namespace
    type(grid_t),                intent(in)    :: gr
    type(kpoints_t),             intent(in)    :: kpoints
    type(opt_control_state_t),   intent(inout) :: qcpsi
    type(ions_t),      optional, intent(in)    :: ions
 
    integer :: i, j
    complex(real64), allocatable :: zpsi(:, :)
    type(states_elec_t), pointer :: psi
 
    push_sub(target_j1_spin)
 
    psi => opt_control_point_qs(qcpsi)
 
    safe_allocate(zpsi(1:gr%np, 1:tg%st%d%dim))
 
    call states_elec_get_state(psi, gr, 1, 1, zpsi)
 
    j1 = m_zero
    do i = 1, 2
      do j = 1, 2
        j1 = j1 + real(tg%spin_matrix(i,j)*zmf_dotp(gr, zpsi(:, i), zpsi(:, j)), real64)
      end do
    end do
 
    safe_deallocate_a(zpsi)
 
    nullify(psi)
    pop_sub(target_j1_spin)
  end function target_j1_spin
 
 
 
  ! ----------------------------------------------------------------------
  subroutine target_chi_spin(tg, namespace, gr, kpoints, qcpsi_in, qcchi_out, ions)
    class(target_spin_t),              intent(inout) :: tg
    type(namespace_t),                 intent(in)    :: namespace
    type(grid_t),                      intent(in)    :: gr
    type(kpoints_t),                   intent(in)    :: kpoints
    type(opt_control_state_t), target, intent(inout) :: qcpsi_in
    type(opt_control_state_t), target, intent(inout) :: qcchi_out
    type(ions_t),                      intent(in)    :: ions
 
    integer :: i, j
    complex(real64), allocatable :: zpsi(:, :), zchi(:, :)
    type(states_elec_t), pointer :: psi_in, chi_out
 
    push_sub(target_chi_spin)
 
    psi_in => opt_control_point_qs(qcpsi_in)
    chi_out => opt_control_point_qs(qcchi_out)
 
    safe_allocate(zpsi(1:gr%np, 1:tg%st%d%dim))
    safe_allocate(zchi(1:gr%np, 1:tg%st%d%dim))
 
    call states_elec_get_state(psi_in, gr, 1, 1, zpsi)
 
    zchi(1:gr%np, 1:tg%st%d%dim) = 0.0_real64
 
    do i = 1, 2
      do j = 1, 2
        zchi(1:gr%np, i) = zchi(1:gr%np, i) + tg%spin_matrix(i, j)*zpsi(1:gr%np, j)
      end do
    end do
 
    call states_elec_set_state(chi_out, gr, 1, 1, zchi)
 
    safe_deallocate_a(zpsi)
    safe_deallocate_a(zchi)
 
    nullify(psi_in)
    nullify(chi_out)
    pop_sub(target_chi_spin)
  end subroutine target_chi_spin
 
end module target_spin_oct_m
 
!! Local Variables:
!! mode: f90
!! coding: utf-8
!! End: