target_tdlocal.F90

Go to the documentation of this file.

!! Copyright (C) 2002-2006 M. Marques, A. Castro, A. Rubio, G. Bertsch
!!
!! This program is free software; you can redistribute it and/or modify
!! it under the terms of the GNU General Public License as published by
!! the Free Software Foundation; either version 2, or (at your option)
!! any later version.
!!
!! This program is distributed in the hope that it will be useful,
!! but WITHOUT ANY WARRANTY; without even the implied warranty of
!! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
!! GNU General Public License for more details.
!!
!! You should have received a copy of the GNU General Public License
!! along with this program; if not, write to the Free Software
!! Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
!! 02110-1301, USA.
!!
 
 
#include "global.h"
 
module target_tdlocal_oct_m
  use batch_ops_oct_m
  use debug_oct_m
  use electron_space_oct_m
  use epot_oct_m
  use global_oct_m
  use grid_oct_m
  use hamiltonian_elec_oct_m
  use interaction_partner_oct_m
  use io_oct_m
  use ions_oct_m
  use ion_dynamics_oct_m
  use io_function_oct_m
  use, intrinsic :: iso_fortran_env
  use kpoints_oct_m
  use mesh_oct_m
  use mesh_function_oct_m
  use messages_oct_m
  use namespace_oct_m
  use opt_control_global_oct_m
  use opt_control_state_oct_m
  use output_low_oct_m
  use parser_oct_m
  use profiling_oct_m
  use restart_oct_m
  use space_oct_m
  use states_elec_oct_m
  use target_oct_m
  use td_oct_m
  use unit_oct_m
  use unit_system_oct_m
 
 
  implicit none
 
  private
  public :: target_tdlocal_t
 
  type, extends(target_t) :: target_tdlocal_t
    private
    real(real64), allocatable :: rho(:)
    real(real64), allocatable :: td_fitness(:)
    character(len=200)        :: td_local_target
  contains
    procedure :: init      => target_init_tdlocal
    procedure :: cleanup   => target_end_tdlocal
    procedure :: j1        => target_j1_tdlocal
    procedure :: apply_chi => target_chi_tdlocal
    procedure :: output    => target_output_tdlocal
    procedure :: tdcalc    => target_tdcalc_tdlocal
    procedure :: inh       => target_inh_tdlocal
  end type target_tdlocal_t
 
 
contains
 
  ! ----------------------------------------------------------------------
  subroutine target_init_tdlocal(tg, gr, kpoints, namespace, space, ions, qcs, td, w0, oct, ep, restart)
    class(target_tdlocal_t),   intent(inout) :: tg
    type(grid_t),              intent(in)    :: gr
    type(kpoints_t),           intent(in)    :: kpoints
    type(namespace_t),         intent(in)    :: namespace
    class(space_t),            intent(in)    :: space
    type(ions_t),              intent(in)    :: ions
    type(opt_control_state_t), intent(inout) :: qcs
    type(td_t),                intent(in)    :: td
    real(real64),              intent(in)    :: w0
    type(oct_t),               intent(in)    :: oct
    type(epot_t),              intent(inout) :: ep
    type(restart_t),           intent(inout) :: restart
 
    type(block_t)       :: blk
    push_sub(target_init_tdlocal)
 
    tg%move_ions = td%ions_dyn%ions_move()
    tg%dt = td%dt
 
    !%Variable OCTTdTarget
    !%Type block
    !%Section Calculation Modes::Optimal Control
    !%Description
    !% (Experimental) If <tt>OCTTargetOperator = oct_tg_td_local</tt>, then you must supply
    !% a OCTTdTarget block. The block should only contain one element, a string cotaining the
    !% definition of the time-dependent local target, <i>i.e.</i> a function of x,y,z and t that
    !% is to be maximized along the evolution.
    !%End
    if (parse_block(namespace, 'OCTTdTarget', blk) == 0) then
      call parse_block_string(blk, 0, 0, tg%td_local_target, convert_to_c=.true.)
      safe_allocate(tg%rho(1:gr%np))
      call parse_block_end(blk)
    else
      message(1) = 'If OCTTargetOperator = oct_tg_td_local, you must supply a OCTTdTarget block.'
      call messages_fatal(1, namespace=namespace)
    end if
    safe_allocate(tg%td_fitness(0:td%max_iter))
    tg%td_fitness = m_zero
    call target_build_tdlocal(tg, gr, m_zero)
 
    pop_sub(target_init_tdlocal)
  end subroutine target_init_tdlocal
 
 
  ! ----------------------------------------------------------------------
  subroutine target_end_tdlocal(tg, oct)
    class(target_tdlocal_t), intent(inout) :: tg
    type(oct_t),             intent(in)    :: oct
 
    push_sub(target_end_tdlocal)
 
    safe_deallocate_a(tg%rho)
    safe_deallocate_a(tg%td_fitness)
 
    pop_sub(target_end_tdlocal)
  end subroutine target_end_tdlocal
 
 
  ! ----------------------------------------------------------------------
  subroutine target_output_tdlocal(tg, namespace, space, gr, dir, ions, hm, outp)
    class(target_tdlocal_t), intent(inout) :: tg
    type(namespace_t), intent(in)    :: namespace
    class(space_t),    intent(in)    :: space
    type(grid_t),      intent(in)    :: gr
    character(len=*),  intent(in)    :: dir
    type(ions_t),      intent(in)    :: ions
    type(hamiltonian_elec_t), intent(in) :: hm
    type(output_t),    intent(in)    :: outp
 
    integer :: ierr
    push_sub(target_output_tdlocal)
 
    call io_mkdir(trim(dir), namespace)
    call target_build_tdlocal(tg, gr, m_zero)
    call dio_function_output(outp%how(0), trim(dir), 'td_local_target', namespace, space, gr, &
      tg%rho, units_out%length**(-space%dim), ierr, pos=ions%pos, atoms=ions%atom)
 
    pop_sub(target_output_tdlocal)
  end subroutine target_output_tdlocal
  ! ----------------------------------------------------------------------
 
 
  ! ----------------------------------------------------------------------
  real(real64) function target_j1_tdlocal(tg, namespace, gr, kpoints, qcpsi, ions) result(j1)
    class(target_tdlocal_t),     intent(inout) :: tg
    type(namespace_t),           intent(in)    :: namespace
    type(grid_t),                intent(in)    :: gr
    type(kpoints_t),             intent(in)    :: kpoints
    type(opt_control_state_t),   intent(inout) :: qcpsi
    type(ions_t),      optional, intent(in)    :: ions
 
    integer :: maxiter
    push_sub(target_j1_tdlocal)
 
    maxiter = size(tg%td_fitness) - 1
    j1 = m_half * tg%dt * tg%td_fitness(0) + &
      m_half * tg%dt * tg%td_fitness(maxiter) + &
      tg%dt * sum(tg%td_fitness(1:maxiter-1))
 
 
    pop_sub(target_j1_tdlocal)
  end function target_j1_tdlocal
 
 
  ! ----------------------------------------------------------------------
  subroutine target_chi_tdlocal(tg, namespace, gr, kpoints, qcpsi_in, qcchi_out, ions)
    class(target_tdlocal_t),           intent(inout) :: tg
    type(namespace_t),                 intent(in)    :: namespace
    type(grid_t),                      intent(in)    :: gr
    type(kpoints_t),                   intent(in)    :: kpoints
    type(opt_control_state_t), target, intent(inout) :: qcpsi_in
    type(opt_control_state_t), target, intent(inout) :: qcchi_out
    type(ions_t),                      intent(in)    :: ions
 
    integer :: ik, ib
    type(states_elec_t), pointer :: chi_out
    push_sub(target_chi_tdlocal)
 
    chi_out => opt_control_point_qs(qcchi_out)
 
    !We assume that there is no time-independent operator.
 
    do ik = chi_out%d%kpt%start, chi_out%d%kpt%end
      do ib = chi_out%group%block_start, chi_out%group%block_end
        call batch_set_zero(chi_out%group%psib(ib, ik))
      end do
    end do
 
    nullify(chi_out)
    pop_sub(target_chi_tdlocal)
  end subroutine target_chi_tdlocal
 
 
  ! ---------------------------------------------------------
  subroutine target_tdcalc_tdlocal(tg, namespace, space, hm, gr, ions, ext_partners, psi, time, max_time)
    class(target_tdlocal_t),  intent(inout) :: tg
    type(namespace_t),        intent(in)    :: namespace
    class(space_t),           intent(in)    :: space
    type(hamiltonian_elec_t), intent(inout) :: hm
    type(grid_t),             intent(in)    :: gr
    type(ions_t),             intent(inout) :: ions
    type(partner_list_t),     intent(in)    :: ext_partners
    type(states_elec_t),      intent(inout) :: psi
    integer,                  intent(in)    :: time
    integer,                  intent(in)    :: max_time
 
    complex(real64), allocatable :: opsi(:, :), zpsi(:, :)
    integer :: ist, ip
    push_sub(target_tdcalc_tdlocal)
 
    tg%td_fitness(time) = m_zero
 
    safe_allocate(zpsi(1:gr%np, 1:psi%d%dim))
 
    !!!! WARNING Here one should build the time-dependent target.
    select case (psi%d%ispin)
    case (unpolarized)
      assert(psi%nik == 1)
      safe_allocate(opsi(1:gr%np_part, 1))
      opsi = m_z0
      do ist  = psi%st_start, psi%st_end
 
        call states_elec_get_state(psi, gr, ist, 1, zpsi)
 
        do ip = 1, gr%np
          opsi(ip, 1) = tg%rho(ip)*zpsi(ip, 1)
        end do
 
        tg%td_fitness(time) = tg%td_fitness(time) + psi%occ(ist, 1)*real(zmf_dotp(gr, psi%d%dim, zpsi, opsi), real64)
 
      end do
      safe_deallocate_a(opsi)
    case (spin_polarized)
      message(1) = 'Error in target.target_tdcalc: spin_polarized.'
      call messages_fatal(1)
    case (spinors)
      message(1) = 'Error in target.target_tdcalc: spinors.'
      call messages_fatal(1)
    end select
 
    safe_deallocate_a(zpsi)
 
    pop_sub(target_tdcalc_tdlocal)
  end subroutine target_tdcalc_tdlocal
  ! ----------------------------------------------------------------------
 
 
  ! ---------------------------------------------------------------
  subroutine target_inh_tdlocal(tg, psi, gr, kpoints, time, inh, iter)
    class(target_tdlocal_t), intent(inout) :: tg
    type(states_elec_t),     intent(inout) :: psi
    type(grid_t),            intent(in)    :: gr
    type(kpoints_t),         intent(in)    :: kpoints
    real(real64),            intent(in)    :: time
    type(states_elec_t),     intent(inout) :: inh
    integer,                 intent(in)    :: iter
 
    integer :: ik, ist, idim
    complex(real64), allocatable :: zpsi(:)
 
    push_sub(target_inh_tdlocal)
 
    safe_allocate(zpsi(1:gr%np))
 
    call target_build_tdlocal(tg, gr, time)
 
    do ik = inh%d%kpt%start, inh%d%kpt%end
      do ist = inh%st_start, inh%st_end
        do idim = 1, inh%d%dim
          call states_elec_get_state(psi, gr, idim, ist, ik, zpsi)
          zpsi(1:gr%np) = -psi%occ(ist, ik)*tg%rho(1:gr%np)*zpsi(1:gr%np)
          call states_elec_set_state(inh, gr, idim, ist, ik, zpsi)
        end do
      end do
    end do
 
    safe_deallocate_a(zpsi)
 
    pop_sub(target_inh_tdlocal)
  end subroutine target_inh_tdlocal
  !----------------------------------------------------------
 
 
  !----------------------------------------------------------
  subroutine target_build_tdlocal(tg, gr, time)
    class(target_tdlocal_t), intent(inout) :: tg
    type(grid_t),   intent(in)    :: gr
    real(real64),   intent(in)    :: time
 
    integer :: ip
    real(real64) :: xx(gr%box%dim), rr, re, im
 
    push_sub(target_build_tdlocal)
 
    do ip = 1, gr%np
      call mesh_r(gr, ip, rr, coords = xx)
      call parse_expression(re, im, gr%box%dim, xx, rr, time, tg%td_local_target)
      tg%rho(ip) = re
    end do
 
    pop_sub(target_build_tdlocal)
  end subroutine target_build_tdlocal
  !----------------------------------------------------------
 
end module target_tdlocal_oct_m
 
!! Local Variables:
!! mode: f90
!! coding: utf-8
!! End: